183 lines
6.3 KiB
HLSL
183 lines
6.3 KiB
HLSL
|
#ifndef UNIVERSAL_SIMPLELIT_GBUFFER_PASS_INCLUDED
|
||
|
|
#define UNIVERSAL_SIMPLELIT_GBUFFER_PASS_INCLUDED
|
||
|
|
|
||
|
|
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
|
||
|
|
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/UnityGBuffer.hlsl"
|
||
|
|
|
||
|
|
// keep this file in sync with LitForwardPass.hlsl
|
||
|
|
|
||
|
|
struct Attributes
|
||
|
|
{
|
||
|
|
float4 positionOS : POSITION;
|
||
|
|
float3 normalOS : NORMAL;
|
||
|
|
float4 tangentOS : TANGENT;
|
||
|
|
float2 texcoord : TEXCOORD0;
|
||
|
|
float2 staticLightmapUV : TEXCOORD1;
|
||
|
|
float2 dynamicLightmapUV : TEXCOORD2;
|
||
|
|
UNITY_VERTEX_INPUT_INSTANCE_ID
|
||
|
|
};
|
||
|
|
|
||
|
|
struct Varyings
|
||
|
|
{
|
||
|
|
float2 uv : TEXCOORD0;
|
||
|
|
|
||
|
|
float3 posWS : TEXCOORD1; // xyz: posWS
|
||
|
|
|
||
|
|
#ifdef _NORMALMAP
|
||
|
|
half4 normal : TEXCOORD2; // xyz: normal, w: viewDir.x
|
||
|
|
half4 tangent : TEXCOORD3; // xyz: tangent, w: viewDir.y
|
||
|
|
half4 bitangent : TEXCOORD4; // xyz: bitangent, w: viewDir.z
|
||
|
|
#else
|
||
|
|
half3 normal : TEXCOORD2;
|
||
|
|
#endif
|
||
|
|
|
||
|
|
#ifdef _ADDITIONAL_LIGHTS_VERTEX
|
||
|
|
half3 vertexLighting : TEXCOORD5; // xyz: vertex light
|
||
|
|
#endif
|
||
|
|
|
||
|
|
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
|
||
|
|
float4 shadowCoord : TEXCOORD6;
|
||
|
|
#endif
|
||
|
|
|
||
|
|
DECLARE_LIGHTMAP_OR_SH(staticLightmapUV, vertexSH, 7);
|
||
|
|
#ifdef DYNAMICLIGHTMAP_ON
|
||
|
|
float2 dynamicLightmapUV : TEXCOORD8; // Dynamic lightmap UVs
|
||
|
|
#endif
|
||
|
|
|
||
|
|
float4 positionCS : SV_POSITION;
|
||
|
|
UNITY_VERTEX_INPUT_INSTANCE_ID
|
||
|
|
UNITY_VERTEX_OUTPUT_STEREO
|
||
|
|
};
|
||
|
|
|
||
|
|
void InitializeInputData(Varyings input, half3 normalTS, out InputData inputData)
|
||
|
|
{
|
||
|
|
inputData = (InputData)0;
|
||
|
|
|
||
|
|
inputData.positionWS = input.posWS;
|
||
|
|
inputData.positionCS = input.positionCS;
|
||
|
|
|
||
|
|
#ifdef _NORMALMAP
|
||
|
|
half3 viewDirWS = half3(input.normal.w, input.tangent.w, input.bitangent.w);
|
||
|
|
inputData.normalWS = TransformTangentToWorld(normalTS,half3x3(input.tangent.xyz, input.bitangent.xyz, input.normal.xyz));
|
||
|
|
#else
|
||
|
|
half3 viewDirWS = GetWorldSpaceNormalizeViewDir(inputData.positionWS);
|
||
|
|
inputData.normalWS = input.normal;
|
||
|
|
#endif
|
||
|
|
|
||
|
|
inputData.normalWS = NormalizeNormalPerPixel(inputData.normalWS);
|
||
|
|
viewDirWS = SafeNormalize(viewDirWS);
|
||
|
|
|
||
|
|
inputData.viewDirectionWS = viewDirWS;
|
||
|
|
|
||
|
|
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
|
||
|
|
inputData.shadowCoord = input.shadowCoord;
|
||
|
|
#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
|
||
|
|
inputData.shadowCoord = TransformWorldToShadowCoord(inputData.positionWS);
|
||
|
|
#else
|
||
|
|
inputData.shadowCoord = float4(0, 0, 0, 0);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
#ifdef _ADDITIONAL_LIGHTS_VERTEX
|
||
|
|
inputData.vertexLighting = input.vertexLighting.xyz;
|
||
|
|
#else
|
||
|
|
inputData.vertexLighting = half3(0, 0, 0);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
inputData.fogCoord = 0; // we don't apply fog in the gbuffer pass
|
||
|
|
|
||
|
|
#if defined(DYNAMICLIGHTMAP_ON)
|
||
|
|
inputData.bakedGI = SAMPLE_GI(input.staticLightmapUV, input.dynamicLightmapUV, input.vertexSH, inputData.normalWS);
|
||
|
|
#else
|
||
|
|
inputData.bakedGI = SAMPLE_GI(input.staticLightmapUV, input.vertexSH, inputData.normalWS);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
inputData.normalizedScreenSpaceUV = GetNormalizedScreenSpaceUV(input.positionCS);
|
||
|
|
inputData.shadowMask = SAMPLE_SHADOWMASK(input.staticLightmapUV);
|
||
|
|
|
||
|
|
#if defined(DEBUG_DISPLAY)
|
||
|
|
#if defined(DYNAMICLIGHTMAP_ON)
|
||
|
|
inputData.dynamicLightmapUV = input.dynamicLightmapUV;
|
||
|
|
#endif
|
||
|
|
#if defined(LIGHTMAP_ON)
|
||
|
|
inputData.staticLightmapUV = input.staticLightmapUV;
|
||
|
|
#else
|
||
|
|
inputData.vertexSH = input.vertexSH;
|
||
|
|
#endif
|
||
|
|
#endif
|
||
|
|
}
|
||
|
|
|
||
|
|
///////////////////////////////////////////////////////////////////////////////
|
||
|
|
// Vertex and Fragment functions //
|
||
|
|
///////////////////////////////////////////////////////////////////////////////
|
||
|
|
|
||
|
|
// Used in Standard (Simple Lighting) shader
|
||
|
|
Varyings LitPassVertexSimple(Attributes input)
|
||
|
|
{
|
||
|
|
Varyings output = (Varyings)0;
|
||
|
|
|
||
|
|
UNITY_SETUP_INSTANCE_ID(input);
|
||
|
|
UNITY_TRANSFER_INSTANCE_ID(input, output);
|
||
|
|
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
|
||
|
|
|
||
|
|
VertexPositionInputs vertexInput = GetVertexPositionInputs(input.positionOS.xyz);
|
||
|
|
VertexNormalInputs normalInput = GetVertexNormalInputs(input.normalOS, input.tangentOS);
|
||
|
|
|
||
|
|
output.uv = TRANSFORM_TEX(input.texcoord, _BaseMap);
|
||
|
|
output.posWS.xyz = vertexInput.positionWS;
|
||
|
|
output.positionCS = vertexInput.positionCS;
|
||
|
|
|
||
|
|
#ifdef _NORMALMAP
|
||
|
|
half3 viewDirWS = GetWorldSpaceNormalizeViewDir(vertexInput.positionWS);
|
||
|
|
output.normal = half4(normalInput.normalWS, viewDirWS.x);
|
||
|
|
output.tangent = half4(normalInput.tangentWS, viewDirWS.y);
|
||
|
|
output.bitangent = half4(normalInput.bitangentWS, viewDirWS.z);
|
||
|
|
#else
|
||
|
|
output.normal = NormalizeNormalPerVertex(normalInput.normalWS);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
OUTPUT_LIGHTMAP_UV(input.staticLightmapUV, unity_LightmapST, output.staticLightmapUV);
|
||
|
|
#ifdef DYNAMICLIGHTMAP_ON
|
||
|
|
output.dynamicLightmapUV = input.dynamicLightmapUV.xy * unity_DynamicLightmapST.xy + unity_DynamicLightmapST.zw;
|
||
|
|
#endif
|
||
|
|
OUTPUT_SH(output.normal.xyz, output.vertexSH);
|
||
|
|
|
||
|
|
#ifdef _ADDITIONAL_LIGHTS_VERTEX
|
||
|
|
half3 vertexLight = VertexLighting(vertexInput.positionWS, normalInput.normalWS);
|
||
|
|
output.vertexLighting = vertexLight;
|
||
|
|
#endif
|
||
|
|
|
||
|
|
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
|
||
|
|
output.shadowCoord = GetShadowCoord(vertexInput);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
return output;
|
||
|
|
}
|
||
|
|
|
||
|
|
|
||
|
|
|
||
|
|
// Used for StandardSimpleLighting shader
|
||
|
|
FragmentOutput LitPassFragmentSimple(Varyings input)
|
||
|
|
{
|
||
|
|
UNITY_SETUP_INSTANCE_ID(input);
|
||
|
|
UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
|
||
|
|
|
||
|
|
SurfaceData surfaceData;
|
||
|
|
InitializeSimpleLitSurfaceData(input.uv, surfaceData);
|
||
|
|
|
||
|
|
InputData inputData;
|
||
|
|
InitializeInputData(input, surfaceData.normalTS, inputData);
|
||
|
|
SETUP_DEBUG_TEXTURE_DATA(inputData, input.uv, _BaseMap);
|
||
|
|
|
||
|
|
#ifdef _DBUFFER
|
||
|
|
ApplyDecalToSurfaceData(input.positionCS, surfaceData, inputData);
|
||
|
|
#endif
|
||
|
|
|
||
|
|
Light mainLight = GetMainLight(inputData.shadowCoord, inputData.positionWS, inputData.shadowMask);
|
||
|
|
MixRealtimeAndBakedGI(mainLight, inputData.normalWS, inputData.bakedGI, inputData.shadowMask);
|
||
|
|
half4 color = half4(inputData.bakedGI * surfaceData.albedo + surfaceData.emission, surfaceData.alpha);
|
||
|
|
|
||
|
|
return SurfaceDataToGbuffer(surfaceData, inputData, color.rgb, kLightingSimpleLit);
|
||
|
|
};
|
||
|
|
|
||
|
|
#endif
|