154 lines
5.6 KiB
HLSL
154 lines
5.6 KiB
HLSL
#ifndef UNIVERSAL_PARTICLES_UNLIT_FORWARD_PASS_INCLUDED
|
|
#define UNIVERSAL_PARTICLES_UNLIT_FORWARD_PASS_INCLUDED
|
|
|
|
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Unlit.hlsl"
|
|
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Particles.hlsl"
|
|
|
|
void InitializeInputData(VaryingsParticle input, SurfaceData surfaceData, out InputData inputData)
|
|
{
|
|
inputData = (InputData)0;
|
|
|
|
inputData.positionWS = input.positionWS.xyz;
|
|
|
|
#ifdef _NORMALMAP
|
|
half3 viewDirWS = half3(input.normalWS.w, input.tangentWS.w, input.bitangentWS.w);
|
|
inputData.tangentToWorld = half3x3(input.tangentWS.xyz, input.bitangentWS.xyz, input.normalWS.xyz);
|
|
inputData.normalWS = TransformTangentToWorld(surfaceData.normalTS, inputData.tangentToWorld);
|
|
#else
|
|
half3 viewDirWS = input.viewDirWS;
|
|
inputData.normalWS = input.normalWS;
|
|
#endif
|
|
|
|
inputData.normalWS = NormalizeNormalPerPixel(inputData.normalWS);
|
|
|
|
#if SHADER_HINT_NICE_QUALITY
|
|
viewDirWS = SafeNormalize(viewDirWS);
|
|
#endif
|
|
|
|
inputData.viewDirectionWS = viewDirWS;
|
|
|
|
inputData.fogCoord = InitializeInputDataFog(float4(input.positionWS.xyz, 1.0), input.positionWS.w);
|
|
inputData.vertexLighting = 0;
|
|
inputData.bakedGI = SampleSHPixel(input.vertexSH, inputData.normalWS);
|
|
inputData.normalizedScreenSpaceUV = GetNormalizedScreenSpaceUV(input.clipPos);
|
|
inputData.shadowMask = 1;
|
|
inputData.shadowCoord = 0;
|
|
|
|
#if defined(DEBUG_DISPLAY) && !defined(PARTICLES_EDITOR_META_PASS)
|
|
inputData.vertexSH = input.vertexSH;
|
|
#endif
|
|
}
|
|
|
|
void InitializeSurfaceData(ParticleParams particleParams, out SurfaceData surfaceData)
|
|
{
|
|
surfaceData = (SurfaceData)0;
|
|
half4 albedo = SampleAlbedo(TEXTURE2D_ARGS(_BaseMap, sampler_BaseMap), particleParams);
|
|
half3 normalTS = SampleNormalTS(particleParams.uv, particleParams.blendUv, TEXTURE2D_ARGS(_BumpMap, sampler_BumpMap));
|
|
|
|
#if defined (_DISTORTION_ON)
|
|
albedo.rgb = Distortion(albedo, normalTS, _DistortionStrengthScaled, _DistortionBlend, particleParams.projectedPosition);
|
|
#endif
|
|
|
|
#if defined(_EMISSION)
|
|
half3 emission = BlendTexture(TEXTURE2D_ARGS(_EmissionMap, sampler_EmissionMap), particleParams.uv, particleParams.blendUv).rgb * _EmissionColor.rgb;
|
|
#else
|
|
const half3 emission = 0;
|
|
#endif
|
|
|
|
surfaceData.albedo = albedo.rgb; // NOTE: Pre-multiplied and modulated in SampleAlbedo().
|
|
surfaceData.specular = 0;
|
|
surfaceData.normalTS = normalTS;
|
|
surfaceData.emission = emission;
|
|
surfaceData.metallic = 0;
|
|
surfaceData.smoothness = 1;
|
|
surfaceData.occlusion = 1;
|
|
surfaceData.alpha = albedo.a;
|
|
|
|
surfaceData.clearCoatMask = 0;
|
|
surfaceData.clearCoatSmoothness = 1;
|
|
}
|
|
|
|
///////////////////////////////////////////////////////////////////////////////
|
|
// Vertex and Fragment functions //
|
|
///////////////////////////////////////////////////////////////////////////////
|
|
|
|
VaryingsParticle vertParticleUnlit(AttributesParticle input)
|
|
{
|
|
VaryingsParticle output = (VaryingsParticle)0;
|
|
|
|
UNITY_SETUP_INSTANCE_ID(input);
|
|
UNITY_TRANSFER_INSTANCE_ID(input, output);
|
|
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
|
|
|
|
VertexPositionInputs vertexInput = GetVertexPositionInputs(input.positionOS.xyz);
|
|
VertexNormalInputs normalInput = GetVertexNormalInputs(input.normalOS, input.tangentOS);
|
|
|
|
half fogFactor = 0.0;
|
|
#if !defined(_FOG_FRAGMENT)
|
|
fogFactor = ComputeFogFactor(vertexInput.positionCS.z);
|
|
#endif
|
|
|
|
// position ws is used to compute eye depth in vertFading
|
|
output.positionWS.xyz = vertexInput.positionWS;
|
|
output.positionWS.w = fogFactor;
|
|
output.clipPos = vertexInput.positionCS;
|
|
output.color = GetParticleColor(input.color);
|
|
|
|
half3 viewDirWS = GetWorldSpaceNormalizeViewDir(vertexInput.positionWS);
|
|
|
|
#ifdef _NORMALMAP
|
|
output.normalWS = half4(normalInput.normalWS, viewDirWS.x);
|
|
output.tangentWS = half4(normalInput.tangentWS, viewDirWS.y);
|
|
output.bitangentWS = half4(normalInput.bitangentWS, viewDirWS.z);
|
|
#else
|
|
output.normalWS = half3(normalInput.normalWS);
|
|
output.viewDirWS = viewDirWS;
|
|
#endif
|
|
|
|
#if defined(_FLIPBOOKBLENDING_ON)
|
|
#if defined(UNITY_PARTICLE_INSTANCING_ENABLED)
|
|
GetParticleTexcoords(output.texcoord, output.texcoord2AndBlend, input.texcoords.xyxy, 0.0);
|
|
#else
|
|
GetParticleTexcoords(output.texcoord, output.texcoord2AndBlend, input.texcoords, input.texcoordBlend);
|
|
#endif
|
|
#else
|
|
GetParticleTexcoords(output.texcoord, input.texcoords.xy);
|
|
#endif
|
|
|
|
#if defined(_SOFTPARTICLES_ON) || defined(_FADING_ON) || defined(_DISTORTION_ON)
|
|
output.projectedPosition = vertexInput.positionNDC;
|
|
#endif
|
|
|
|
return output;
|
|
}
|
|
|
|
half4 fragParticleUnlit(VaryingsParticle input) : SV_Target
|
|
{
|
|
UNITY_SETUP_INSTANCE_ID(input);
|
|
UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
|
|
|
|
ParticleParams particleParams;
|
|
InitParticleParams(input, particleParams);
|
|
|
|
SurfaceData surfaceData;
|
|
InitializeSurfaceData(particleParams, surfaceData);
|
|
InputData inputData;
|
|
InitializeInputData(input, surfaceData, inputData);
|
|
SETUP_DEBUG_TEXTURE_DATA(inputData, input.texcoord, _BaseMap);
|
|
|
|
half4 finalColor = UniversalFragmentUnlit(inputData, surfaceData);
|
|
|
|
#if defined(_SCREEN_SPACE_OCCLUSION) && !defined(_SURFACE_TYPE_TRANSPARENT)
|
|
float2 normalizedScreenSpaceUV = GetNormalizedScreenSpaceUV(input.clipPos);
|
|
AmbientOcclusionFactor aoFactor = GetScreenSpaceAmbientOcclusion(normalizedScreenSpaceUV);
|
|
finalColor.rgb *= aoFactor.directAmbientOcclusion;
|
|
#endif
|
|
|
|
finalColor.rgb = MixFog(finalColor.rgb, inputData.fogCoord);
|
|
finalColor.a = OutputAlpha(finalColor.a, _Surface);
|
|
|
|
return finalColor;
|
|
}
|
|
|
|
#endif // UNIVERSAL_PARTICLES_UNLIT_FORWARD_PASS_INCLUDED
|